クオーツ時計を100倍速&リバースモード付きに改造してみた。

2015/02/08

お疲れ様です。高橋です。

今日、奥さんから壊れた時計を貰いました。電池を入れ替えても針の進みが良くないとの事です。早速分解してみます。

時計の中身

裏蓋を外すと、ムーブメントが見えてきます。

さらに時針分針秒針と、ムーブメントを分解。

ムーブメント自体も分解。

そしてこの基板が時計のご本尊。電池からの+と-を受け付け、更に金属のケースに覆われた水晶を使って、裏側にあるコイル(電磁石)に定期的(時計なので1秒毎)に電気を流して、時計の針に達する磁石付きの歯車をピクッピクッと動かしています。

改造

Arduinoからは任意のタイミングで電気を流せるので、時計側の基板に付いている水晶は不要。なので、コイルから伸びている2本の線をArduinoから操作出来るように半田付けします。

とても細い線なので、慎重に一本目。

続いてもう一本も。

そして、歯車を元に戻し、時針分針秒針を挿して動作確認。電気を+と-を交互に入れ替えないと針が進みません。Arduino側でプログラムを書く際は、ここを気をつけないといけません。

この動画では、私自身が手動で発振子の役割と、プラスマイナスの電気の向きを交互に変えているのがわかると思います。

Arduino側から操作

配線は至って簡単で、コイルから伸びている2本の線を、適当なデジタルピンに挿します。今回はデジタル2番と4番に挿します。赤と白はどっちでも構いません。

そして、スケッチは下記の通りとなります。

int a = 2;
int b = 4;
bool isA = false;
const int pulse_time = 20;
int delay_milsec=1000;

void pulse_reverse() {
 if (isA) {
 digitalWrite(a, HIGH);
 delay(50-pulse_time);
 digitalWrite(a, LOW);
 delay(pulse_time);
 } 
 else {
 digitalWrite(b, HIGH);
 delay(50-pulse_time);
 digitalWrite(b, LOW);
 delay(pulse_time);
 }
 isA = !isA;
}

void pulse() {
 if (isA) {
 digitalWrite(a, HIGH);
 delay(pulse_time);
 digitalWrite(a, LOW);
 delay(50-pulse_time);
 } 
 else {
 digitalWrite(b, HIGH);
 delay(pulse_time);
 digitalWrite(b, LOW);
 delay(50-pulse_time);
 }
 isA = !isA;
}

void setup() {
 digitalWrite(a, LOW);
 digitalWrite(b, LOW);
 pinMode(a, OUTPUT);
 pinMode(b, OUTPUT);
}

void loop() 
{
 pulse();
 myDelay();
 /*
 for(int i = 0 ; i < 10; i++) {
 pulse();
 myDelay();
 }
 for(int i = 0 ; i < 10; i++) {
 pulse_reverse();
 myDelay();
 }
 */
}

void myDelay() {
 float input_delay = (float)map(analogRead(A4),0,1023,1,100)/100.0;
 if(input_delay > 0.6 ) input_delay=1;
 delay(delay_milsec * input_delay);
}

aとbが2本の線を示すデジタルピンの番号です。どっちがどっちでも構いません。

booleanのisAは、aとbから交互に電気を流すためのスイッチ的役割です。

pulse_time はAとBに流す電気の時間的長さです。色々調整しましたが、20msecがちょうどいい感じでした。

delay_milsecは、電気を流す時の間隔です。時計なので、1秒に1回電気が流れるべきなので、1000msec(=1秒)にしています。

pulse_reverse() は、反時計回り、pulse()は時計回りです。

最初は10回毎に時計回りと反時計回りを交互に繰り返すプログラムを書いていたのですが、スイッチか何かでモードを切り替えようと思ったまま、結局面倒になってやめました。コメントアウトされている箇所は、それの名残です。

そして、myDelay()では、別途可変抵抗器(アナログ4番)から読み込む値を持って、針の速度を決定します。1倍～100倍までの速度が得られます。